0 POKE53280,.:POKE53281,.:POKE808,225
1 PRINT"[147][155]MANIPULATE-A-GANGSTER          [151]BRAINBIRD"
2 PRINT"[152]1 - MAKE GANGSTER":PRINT"2 - SHOW GANGSTER"
3 PRINT"3 - SCRATCH GANGSTER":PRINT"4 - DIR":PRINT"5 - INFO"
4 PRINT"0 - QUIT[144]"
5 GOSUB80:IFASC(Q$)<48ORASC(Q$)>53THEN5
6 Q=VAL(Q$):Q=Q+1:ONQGOTO96,10,20,40,50,60:GOTO4
10 PRINT"[147][155]GANGSTER-MAKER                 [151]BRAINBIRD"
11 INPUT"[152]GANGSTER-NUMMER ";Z$:GOSUB83
12 INPUT"NAME ";GN$:INPUT"WAFFE";GW$:INPUT"EIG. ";GE$:INPUT"PREIS";P
13 INPUT"KOMM.";X$
14 OPEN1,8,2,"GAN"+Z$+",S,W"
15 PRINT#1,GN$:PRINT#1,GW$:PRINT#1,GE$:PRINT#1,P:PRINT#1,X$
16 CLOSE1:Z$="0"
19 GOSUB80:GOTO0
20 PRINT"[147][155]GANGSTER-SHOW                  [151]BRAINBIRD"
21 INPUT"[152]GANGSTER-NUMMER ";Z$:GOSUB83
22 OPEN1,8,2,"GAN"+Z$+",S,R"
23 INPUT#1,GN$,GW$,GE$,P,X$
24 CLOSE1:Z$="0"
25 PRINT"NAME :";GN$:PRINT"WAFFE:";GW$:PRINT"EIG. :";GE$:PRINT"PREIS:";P
26 PRINT"KOMM.:";X$
29 GOSUB80:GOTO0
40 PRINT"[147][155]GANGSTER-SCRATCHER             [151]BRAINBIRD"
41 INPUT"[152]GANGSTER-NUMMER ";Z$:GOSUB83
43 OPEN1,8,15,"S:GAN"+Z$+",S,R"
44 CLOSE1:Z$="0"
49 GOSUB80:GOTO0
50 PRINT"[147][152]":OPEN1,8,0,"$"
51 GET#1,A$,A$
52 GET#1,A$,A$:IFST=64THENCLOSE1:GOSUB80:GOTO0
53 GET#1,A$,B$:PRINTASC(A$+CHR$(0))+256*ASC(B$+CHR$(0));
54 GET#1,A$:PRINTA$;:IFA$<>""THEN54
55 PRINT:GOTO52
60 PRINT"[147][155]INFO MANIPULATE-A-GANGSTER     [151]BRAINBIRD"
62 PRINT"GANGSTER-DESIGNER ZU MAFIA,DAS SPIEL.[152]   ANWENDUNG:":PRINT"NAME";
63 PRINT"...EINGABE DES NAMEN (KLAR)":PRINT"WAFFE..ZAHL ZWISCHEN 0-8."
64 PRINT"        0=HAENDE,8=HANDGRANATEN":PRINT"EIG....EIGENSCHAFTEN:SECHS";
65 PRINT"STELLIGE ZAHL":PRINT"        ERSTE ZWEI ZIFFERN =L.PUNKTE":PRINT"    ";
66 PRINT"    ZWEITE ZWEI ZIFFERN=INTELLIGENZ":PRINT"        DRITTE ZWEI ZIFFER";
67 PRINT"N=BRUTALITAET":PRINT"PREIS..WAS WOHL ?":PRINT"KOMM...KOMMENTAR.";
68 PRINT"DARF MAX ZWEI ZEILEN           LANG SEIN.":PRINT"[155]DIES IST EINE VOR";
69 PRINT"VERSION...KEIN GEMOTZE!NICHT IDIOTENSICHER !!!":PRINT"TIP:";
70 PRINT"ZUERST EINEN GANGSTER LADEN,UM EINENUEBERBLICK ZU BEKOMMEN..."
71 PRINT"[152]IM EDITOR KEIN KOMMA<,> SONDERN <@>.":PRINT"ZB:BRAINBIRD@DAS GENIE";
72 PRINT" (NUR'N BEISPIEL)":PRINT"NUR GAN-NUMMERN ZWISCHEN 1-30!"
79 GOSUB80:GOTO0
80 GETQ$:IFQ$=""THEN80
81 RETURN
83 Z=VAL(Z$):IFZ=0THEN0
84 RETURN
96 PRINT"SICHER ?":GOSUB80
97 IFQ$="J"THEN99
98 GOTO0
99 SYS64738